VAN de renta constante

Aplicando una tasa de 10% efectivo anual, calcular el VAN de una operación de inversión cuyo desembolso es de 70.000 € y consta de 8 recuperaciones semestrales de 12.000 € cada una.

---

Ver el siguiente Post:

VAN y TIR

Método 1

El método 1, consiste en aplicar la fórmula =VNA.

=VNA(tasa; flujos del 1 al n)+flujo en t=0

=VNA(F10;C11:C18)+C10

Método 2

El método 2, no es muy aconsejable, ya que consiste en trabajar poniendo cada flujo de caja, en lugar de trabajar con rangos, que sería lo aconsejable. Pero para verlo una vez, no está mal, aunque no se aconseja este método. Sería así:

=VNA(1,1^0,5-1;12000;12000;12000;12000;12000;12000;12000;12000)-70000

Método 3

Gracias a que estamos en una operación de inversión donde todas las recuperaciones son iguales, se puede aplicar la fórmula VA. La fórmula de Excel =VA sirve para calcular el valor actual de rentas de cuantía constante.

=VA(tasa;nper;va)

=VA(F10;8;-12000)-70000

---

Pregunta

¿Por qué al calcular el VAN se pone al final el valor de la inversión inicial fuera de la fórmula VNA?

Respuesta

La función de Excel =VNA tiene la siguiente sintaxis:

=VNA(tasa;rango)

donde

tasa es el tanto efectivo relativo al periodo con el que se produce la renta. Si la renta es mensual, el tanto necesariamente ha de ser un mensual efectivo. Si la renta fuera de periodicidad trimestral, el tanto necesariamente ha de ser un trimestral efectivo.

rango es el rango donde se encuentran los flujos de caja, comenzando por el que vence en t=1. No se incluye el que vende en t=0, ya que esta función esta diseñada para rentas pospagables. Si tenemos que incluir el flujo que vence en t=0, como así ocurre en una inversión, con el desembolso inicial, éste se sumaría fuera de la función VNA.


La función VNA es una función que esta pensada para rentas POSPAGABLES. Esto es, el primer término de la renta (la primera cuantía) vence en t=1, y nosotros deseamos valorar a Valor Actual (en t=0).

Si la renta fuera PREPAGABLE, como sucede en el caso de las operaciones de inversión donde existe un desembolso inicial en t=0, para calcular el VAN de la operación, se debe usar la función =VNA aplicada a los flujos de caja desde t=1 hasta el final, y luego sumar, fuera de la función VNA, el flujo de caja que vence en t=0. Esto de sumar fuera el desembolso inicial no es debido a que sea negativo, sino a que vence en t=0.

Si la renta fuera PREPAGABLE y se incluyeran todos los flujos de caja en la función =VNA, incluso el desembolso inicial que vence en t=0, la renta quedaría valorada no en el instante t=0, sino en el instante t=-1 (un periodo antes del cero), debido a la propia naturaleza de la función, que esta pensada para rentas pospagables. Y al quedar valorada en t=-1, deberíamos capitalizar un periodo para llegar a situar su valor financiero en t=0, y así tener calculado el Valor Actual. Si quieres puedes hacer la comprobación, y verás
que también funciona, pero a nivel conceptual, creo que es mejor que nos acostumbremos a trabajar con VNA aplicado a la renta pospagable y luego sumar fuera de la fórmula el flujo de caja que vence en t=0.

---

Si calculamos la TIR nos da: 7,61% efectivo anual.

El problema pide calcular el VAN al 10%. Pero podría haber pedido calcular el VAN al 15% o al 3%. La tasa de descuento k a la que nos pidan al calcular el VAN, no tiene porque ser la TIR de la operación. Lo que si sabemos es que si calculas el VAN justo a una tasa de descuento k que coincida con la TIR, entonces el VAN te dará CERO.

Pruébalo, calcula el VAN a una tasa justo del 7,60705434399175%, que es la TIR de la operación, y veras que da cero.

Por tanto, en este problema el 10% del que habla el enunciado no tiene nada que ver con la TIR de la operación.

Vídeo

Audio

VAN

Aplicando una tasa del 8,0% efectivo anual, calcular el VAN de una operación de inversión con las siguientes características. Desembolso de 1.100.000 €, siendo las recuperaciones de 200.000 € transcurrido un trimestre, 300.000 € transcurridos dos trimestres más, 400.000 € transcurrido un trimestre más, y 500.000 € transcurridos cuatro trimestres más. La duración total la operación es de dos años.

---

Método 1

Trabajando en trimestres y con el i4.

=VNA(F12;C13:C20)+C12

Método 2

=+VNA(1,08^0,25-1;200000;0;300000;400000;0;0;0;500000)-1100000

El método 2 no es aconsejable. Lo adecuado es que al trabajar con las funciones financieras utilicemos rangos.

Método 3

Planteando los flujos en trimestres hemos obtenido el método 1. Para ello hemos puesto como cero los flujos donde no existe cuantía en ese periodo. La función =VNA es la siguiente:

=VNA(tasa;rango)

donde

tasa es el tanto efectivo relativo al periodo con el que se produce la renta. Si la renta es mensual, el tanto necesariamente ha de ser un mensual efectivo. Si la renta fuera de periodicidad trimestral, el tanto necesariamente ha de ser un trimestral efectivo.

rango es el rango donde se encuentran los flujos de caja, comenzando por el que vence en t=1. No se incluye el que vende en t=0, ya que esta función esta diseñada para rentas pospagables. Si tenemos que incluir el flujo que vence en t=0, como así ocurre en una inversión con el desembolso inicial, éste se sumaría fuera de la función VNA.

Si planteamos los flujos en meses, y entonces tendremos que meter muchos más ceros en los flujos de caja donde no venza una cuantía. Al calcular la función VNA debemos trabajar con el efectivo mensual (i12).

Trabajando en meses y con el i12.

=VNA(F24;C25:C48)+C24

Vídeo

Audio

TIR de una renta constante

Calcular la TIR de una operación de inversión con las siguientes características: Desembolso de 100.000 €. Siendo las recuperaciones de 10.000 € mensuales durante un año.

---

Métodos 1, 2 y 3

Método 4

La celda C28 es: =+VA((1+C27)^(1/12)-1;12;-10000)+C11

Vídeo

TIR

Calcular la TIR de una operación de inversión con las siguientes características: Desembolso de 100.000 €. Siendo las recuperaciones de 10.000 € mensuales durante un año, salvo el 3º mes que no se recupera nada y el mes 9º donde se perciben 20.000 €.

---

Método 1

Método 2

Vídeo

VF

Calcular el valor final de una renta de 120 términos mensuales, prepagables, constantes de 1.000 €, valorada al 7% efectivo anual.

---

Método 1

Usando la formula de VF:

=VF(tasa;nper;pago;va;tipo)

=VF(i12;120;-1000;;1)

i12 es el i mensual calculado a partir de =(1+7%)^(1/12)-1

el último valor de VF es 1 porque se trata de una renta prepagable.

Método 2

Aplicando la fórmula. Este método no es el más aconsejable, ya que con la función VF se trabaja mejor.

---

Los símbolos siguientes representan:

1. Valor actual de una renta unitaria (de cuantía constante 1 €), pospagable, de n términos, valorada al tanto i.
2. Valor actual de una renta unitaria prepagable, de n términos, valorada al tanto i.
3. Valor final de una renta unitaria, pospagable, de n términos, valorada al tanto i.
4. Valor final de una renta unitaria prepagable, de n términos, valorada al tanto i.

Para pasar de una renta PRE a una renta POS multiplicamos por (1+i).

Vídeo

Audio

VA de una perpetua diferida

Calcular el valor actual de una renta perpetua de 10.000 € anuales, donde se percibe el primero dentro de 5 años. Valorar al 10% anual.

---

Método 1

Después de calcular el valor actual de una renta perpetua debemos descontar 4 años, ya que ese valor actual quedaría valorado en t=4.

=10000/0,1/1,1^4

Método 2

=+VA(10%;1000;-10000)/1,1^4

El método 2, se puede calcular usando la función VA con un valor de nper de 1.000 periodos (u otro valor muy grande), y luego descontar el número de años suficientes (esa es la clave).

Método 3

Considerando la renta PRE y luego descontando 5 años.

=+VA(10%;1000;-10000;;1)/1,1^5

Vídeo

Audio

Tasa de un VA

De una renta prepagable, de 500 € mensuales y duración un año, sabemos que su valor actual es de 5.700 €. Calcular el tanto efectivo anual al que se calculó el valor actual.

---

El método 1 se resuelve con la función TASA, que en este caso es el método más rápido, ya que no se precisa hacer la tabla con los flujos de caja.

Cuando el flujo de caja que es cero está al final, para calcular la TIR, da igual incluirle o
no.

En la celda H11 puedes poner la fórmula:

=TIR(E10:E21)

que como ves, llega hasta la fila 21, no incluyendo el flujo de caja en t=12.

El motivo es que al ser el último no influye en la operación, de la misma forma que no
influye el siguiente (que tampoco existe), ni el siguiente, etc.

Si el que falta es un flujo de caja intermedio es obligatorio poner cero, en lugar de dajar
la celda vacía.

---

Los tres siguientes conceptos son en realidad el mismo:

• Tanto Efectivo Anual: i
• TIR
• TAE

Trabajando con una operación simple (una sola cuantía de la prestación (Co), y una única cuantía para la contraprestación (Cn)), podemos aplicar la ley de capitalización compuesta:

Cn=Co(1+i)^n

y despejar a mano i. Esto es, podemos despejar a mano la TIR.

Pero en una operación compleja, donde intervienen múltiples cuantías, despejar la TIR a mano es imposible, por lo que se requiere usar un ordenador.

Vídeo

Constituir un montante

Un agricultor desea adquirir un tractor dentro de 4 años por importe de 60.000 €. Para ello decide ahorrar efectuando aportaciones trimestrales de 3.000 €, comenzando hoy mismo la primera. El depósito se remunera al 6% nominal anual. Es consciente de que a pesar de las 16 aportaciones realizadas al fondo, no llegará al montante necesario y tendrá que pagar, dentro de 4 años, un importe X para poder adquirir el tractor. Calcular X.

---

Veamos la comprobación de la celda F21

=+(VNA(F15;C14:C29)+C13)*(1+F15)^16

En esta fórmula lo que hacemos es calcular el valor final (VF) de toda la renta. La renta es variable, ya que la mayor parte del tiempo se pagan 3.000 euros, pero justo al final se pagan X euros. Al ser la renta de cuantía variable no puedo usar la función =VF de Excel, ya que ésta se usa únicamente para calcular el valor final de rentas de cuantía constante.

¿Existe en Excel alguna función que calcule el Valor Final del rentas de cuantía variable, al igual que la función VNA permite calcular el Valor Actual de este tipo de rentas?

La respuesta es NO.

Pero lo que hacemos es calcular primero el valor actual con la función VNA y luego capitalizamos hasta llegar a valor final.

Para calcular el valor actual podemos hacer esto:

VNA(F15;C14:C29)+C13

y luego capitalizar 16 trimestres, para llegar a obtener el valor final:

=+(VNA(F15;C14:C29)+C13)*(1+F15)^16

Veamos la comprobación de la celda F22

Si en la función VNA se incluyen todos los flujos de caja, incluido el que vence en t=0, lo que se obtiene no es el valor actual de la renta sino el valor en t=-1 (un periodo antes de cero). Esto justifica que podamos utilizar la siguiente expresión, para hacer la comprobación:

=+VNA(F15;C13:C29)*(1+F15)^17

Observar que elevamos a 17 trimestres.

Vídeo

Resuelto con ecuaciones

Audio

Aportación a un fondo

Calcular la aportación mensual constante y prepagable que se ha de realizar para poder constituir un montante de 100.000 €, en 5 años, si se aplica un 6% nominal anual.

---

Nos dan un tanto nominal anual del 6%.

j12=6%

i12=6%/12= 0,5% efectivo mensual

En la renta tenemos que trabajar con el 0,5% efectivo mensual.

La renta es prepagable. Por tanto, la primera aportación se produce en t=0, y la última en t=59. En total hay 60 aportaciones mensuales, y en el instante t=60 no se aporta nada (se deja la celda vacía).

Nos piden la aportación necesaria para llegar a un montante M=100.000 euros.

Método 1


Planteamos la equivalencia financiera, en t=60 entre prestación y contraprestación.

Podríamos hacer ese cálculo en una celda, usando Excel como si fuera una calculadora. Pero eso no es lo más aconsejable. Lo mejor es usar las funciones que nos proporciona la Hoja de Cálculo. En este caso podemos usar la función VF que calcula el valor final de una renta de cuantía constante.

=VF(tasa;nper;pago;va;tipo)

donde:


tasa es es tipo de interés efectivo. Tiene que ser el que tenga la misma unidad temporal que marca la periodicidad de la renta. Si la renta es mensual, debemos necesariamente trabajar con el efectivo mensual.


nper: indica el número de términos de la renta. Siempre es un número entero. Una renta no puede tener 5,37 términos.


pago: es el término constante de la renta. Se pone negativo para evitar que el valor que nos de la función se negativo.


va: normalmente este dato no se pone. Cuando se pone es que además de la renta periódica se paga una cantidad adicional en t=0. Esa cantidad adicional es la que se pone aquí también con signo negativo.


tipo: no es el tipo de interés. Hace referencia al tipo de renta. Si la renta es pospagable no se pone dada. Si la renta es prepagable se ponen un 1.

Para este problema, podemos calcular la cuantía de la aportación dividiendo 100.000 entre el valor final de una renta unitaria (de cuantía constante 1 euro), prepagable, de 60 términos mensuales, valorada al 0,5% mensual. Esto es:

=100000/VF(F11;60;-1;;1)

Observar que en va se pone -1, ya que la renta es unitaria.

Método 2


Existe una función maravillosa en Excel que se llama PAGO, y que utilizaremos intensivamente en préstamos. En los préstamos la utilizaremos para calcular cuál es el pago periódico necesario para amortizar el principal del préstamo, en el tiempo que nos digan, y aplicando el tipo de interés pactado. Pero eso ya lo veremos en su día.

La función PAGO también puede servir para calcular el importe de la aportación constante que debemos realizar a un fondo de constitución de capital para llegar a obtener un montante final, realizando un cierto número de aportaciones, y capitalizándolas a un tipo de interés constante pactado.

=PAGO(tasa;nper;va;vf;tipo)

donde:

tasa es el tipo de interés constante pactado y ha de tener la misma unidad temporal que la renta. Si la renta es mensual el tanto ha de ser necesariamente un tanto efectivo mensual.


nper indica el número de términos de la renta. Es siempre un número entero.
va es el valor actual. En el caso de un préstamo es el importe del principal solicitado. Es un número negativo para evitar que la función nos de valores negativos.


vf es el valor final. En el caso de una operación de constitución de capital, sería el montante al que queremos llegar


tipo indica el tipo de renta. Si la renta es pospagable no se pone nada. Si la renta es prepagable se pone un 1. Las operaciones de constitución normalmente son prepagables, ya que en caso contrario no tendría mucho sentido entregar la última aportación justo en el momento en el que se retira el capital constituido. Por el contrario, las operaciones de préstamo, normalmente, son operaciones pospagables. Esto quiere decir que comenzamos a pagar un periodo después de que nos entregen el importe del principal.

En este caso, es una maravilla poder resolver este problema en una única celda:

=PAGO(6%/12;60;;-100000;1)

Podemos hacer la comprobación en la celda G18:

=+VF(G11;60;-G15;;1)

Método 3

Desarrollando la fórmula, tal y como lo haríamos con calculadora, pero este no es el método más aconsejable.

=100000*0,005/1,005/(1,005^60-1)


Método 4

También se puede resolver con Solver, haciendo que precisamente la formula que aquí usamos como comprobación, dependa de un pago (C) que nos inventamos, y que Solver se encargará de calcular, para conseguir que el montante final sea justo de 100.000 euros.

Vídeo

Audio