Equivalencia Financiera

En una operación financiera pactada al 7% efectivo anual, la prestación está compuesta por los siguientes capitales financieros: (500.000;0), (100.000;1), (300.000;3), (600.000;5), (500.000;9) y (900.000;10). Y la contraprestación la integran los siguientes capitales financieros: (450.000;1), (280.000;2),(700.000;4), (X;7),(700.000;8) y (500.000;9). Donde los capitales financieros están expresados en forma de (C;t), cuantía en euros y vencimiento en años. Calcular X.

---

Consulta este Post:

Equivalencia Financiera y Reserva Matemática

Método 1

Método 2

La celda D28 que contiene el Va de la Prestación tiene la siguiente fórmula:

=VNA(C12;C16:C25)+C15

La función VNA esta pensada para rentas pospagables, y cuando queremos calcular el VA de una renta prepagable entonces el valor que vence en t=0, se ha de sumar fuera de la función.

La Celda D30 es: =REDONDEAR(D29;6)=REDONDEAR(D28;6)

Hemos necesitado redondear a 6 decimales, ya que Solver puede cometer alguna pequeña imprecisión.

Método 3

En una sola celda podemos calcular X.

=(VNA(C12;C16:C25)+C15)*(1+C12)^7-VNA(C12;D23:D25)-(VNA(C12;D16:D21)*(1+C12)^7)

Método 4

Método 5

En una sola celda podemos calcular X.

=(VNA(C12;C35:C44)+C34)*(1+C12)^7-VNA(C12;D35:D44)*(1+C12)^7

Método 6

Vídeo

Reserva Matemática

Calcular la Reserva Matemática por la derecha en t=5 del problema anterior.

---

Consulta este Post:

Equivalencia Financiera y Reserva Matemática

La Reserva Matemática o Saldo Financiero de una Operación Financiera se puede calcular por tres métodos:

1. Método recurrente
2. Método retrospectivo
3. Método prospectivo

Consultar el Libro de Cálculo Financiero. Como veremos en Préstamos es importante conocer bien los tres métodos.

El método recurrente es el de las dos columnas R- y R+, pero luego es conveniente también ver los métodos retrospectivo y prospectivo, ya que luego se usan en préstamos.

• La celda D26 es: =G19
• La celda D27 es: =(VNA(C11;C15:C19)+C14)*(1+C11)^5-(VNA(C11;D15:D19)+D14)*(1+C11)^5
• La celda D28 es: =VNA(C11;D20:D24)-VNA(C11;C20:C24)

Método Retrospectivo

En este caso el método retrospectivo nos permite calcular la reserva matemática en t=5 por la derecha sin necesidad de calcular previamente el valor de x.

Geométrica fraccionada

Una asociación pretende ahorrar al inicio de cada mes durante 10 años cierto importe creciente, que el primer mes es de C €. Dentro de cada semestre las aportaciones al fondo son constantes y se incrementan semestralmente un 5% semestral acumulado. Determinar C sabiendo que el montante alcanzado ha sido de un millón de euros. Valorar al 10% nominal anual.

---

Vea en el blog la parte teórica necesaria para comprender cómo se resuelve este caso.

• Valoración de una renta geométrica fraccionada

---

No estamos en el caso en que q=1+i.

q=1,05 esto supone incrementos acumulados del 5% semestral.

La renta es mensual. Nos dan un j12=10% nominal anual (fraccionamiento mensual).

Calculamos i12, y luego i2

Sale que i2 no es el 5%, es:

i2=5,10533133201649%

Por tanto, no estamos en el caso en que q=1+i, que adaptado a esta caso, tendríamos que decir que:

"no estamos en el caso en el que q=1+i2"

1,05 es distinto de 1,0510533133201649

El tanto 0,8333% es el tanto efectivo mensual, i12.

Debemos aplicar la fórmula general para las rentas variables en progresión geométrica.

Método 1

Es una renta PRE (comienza en t=0), es de 120 términos mensuales. Vamos a inventarnos el primero de ellos, por ejemplo 5.000 euros. Comprueba que en ese caso el último término es de importe: 12.634,75euros.

Calcula en una celda el VAN, lógicamente a una tasa:

i12=5,10533133201649%

Veras que te da un importe de: 582.177,040100061

Como queremos el montante, debes calcular el VF capitalizando esa cifra 120 meses al tanto i12, o 10 años al tanto i. Elige el método que más te guste:

M=1.575.977,40

Ahora pide a Solver que cambie la celda primera, la de la primera mensualidad, para conseguir que M sea justo de un millón. Para que esto funcione, todas las celdas de la renta tienen que estar ligadas a esa primera celda mediante fórmula.

Si todo ha ido bien, te saldrá que la primera mensualidad es:

a=3.172,63 euros

y la última mensualidad es:

a*1,05^19 = 8.017,09 euros

Y el Montante es justo de un millón de euros.

Hasta aquí el Método 1, que es el de Solver.

Como ves hasta ahora no hemos utilizado para nada el tanto efectivo semestral i2.

Resumiendo el Método 1:

• Nos inventamos el valor de C, por ejemplo, 5.000 euros.
• Calculamos los términos de la renta. Mirar la fórmula de la celda C18.
• Recordar que por ser una renta prepagable en t=120 no vence cuantía.
• Calculamos el Valor Final de la renta, y su Diferencia con un millón de euros.
• Pedimos a Solver que calcule C para hacer esa Diferencia cero.

Observa que en Solver indicamos que la celda que deseamos despejar es C12. Pero no olvides que todas las demás del primer semestre (desde la C13 a la C17) están vinculadas con dólares a la C12, para que todas ellas sean iguales.

La fórmula que nos permite calcular el montante M en la celda F17 es:

=(VNA(F13;C13:C131)+C12)*(1+F15)^10

Recuerda que en 120 no se pone nada por ser una renta prepagable.

Método 2

• Celda F21: =1000000/VFgeo(1;F11;20;F14)
• Celda F22: =F21/VF(F13;6;-1;;1)

Método 3

Podemos calcularlo en una sola celda combinando la función PAGO y VFgeo.

=PAGO(F13;6;;-1000000/VFgeo(1;F11;20;F14);1)

Podemos aprender a programar VFgeo y VAgeo en el siguiente Post que tiene un vídeo:

Valor Financiero de una Renta Geométrica. VAGEO

Comprobación:

Celda F27: =VF(F13;6;-C12;;1)

Celda F28: =VFgeo(F27;F11;20;F14)

Celda F29: =VNA(F13;C12:C131)*(1+F15)^(121/12)

Celda F30: =F27*(1-(F11/(1+F14))^20)/(1+F14-F11)*(1+F15)^10

Método 4

Vamos a calcular una renta semestral pospagable equivalente financieramente a la renta mensual prepagable.

Para ello, inicialmente en F35 nos inventamos el valor de la primera mensualidad, por ejemplo a= 5.000 euros.

Diseñamos un cuadro con 20 semestres donde la primera semestralidad pospagable está en la celda F39 y su fórmula es:

=VF(F13;6;-F35;;1)

Para obtener las siguienes semestralidades debemos multiplicar el valor obtenido por la razón SEMESTRAL de la progresión geométrica que es q=1,05. La fórmula de la celda F40 es la siguientes, y se ha de copiar hacia abajo.

=F39*$F$11

Ahora calculamos en la celda F60 el montante alcanzado. Para ello calculamos el VAN y luego capitalizamos. La fórmula es:

=VNA(F14;F39:F58)*(1+F15)^10

En esta ocasión estamos utilizando el tanto semestral i2 que está en la celda F14. Ha sido necesario utilizarle puesto que estoy en este caso trabajando con una renta SEMESTRAL.

Ahora pido a solver que haga que el montante M sea de un millón de euros, y si todo va bien, habre calculado la primera mensaulidad de la celda F35.

Recapitulemos. Como ves lo que hago es transformar una renta mensual en otra semestral equivalente, y luego trabajo con la semestral. Por ese motivo necesito tanto el i12 como el i2. El i12 lo necesito cuando trabajo con la renta mensual, y el i2 lo necesito cuando trabajo con la renta semestral. Pero no olvides que podríamos haber resuelto este problema (método 1) sin necesidad de utilizar para nada el tanto semestral i2. El hecho de clacular i2 ha sido por la necesidad que tengo de valorar una renta semestral.

Cuando uso VAgeo, la idea es la misma, ya que VAgeo no trabaja directametne sobre la renta mensual, ya que ésta no es una renta variable en progresión geométrica. Sino que VAgeo trabaja sobre la renta semestral equivalente, que esa si es SEMESTRAL.

La celda H35 es simplemente una comprobación, que proporciona un sistema curioso de obtener a. Su expresión es la siguiente.

=PAGO(F13;6;;-F39;1)

Método 5

Mira el siguiente Post que incluye un vídeo para programar VAgeo y VFgeo.

Valor Financiero de una Renta Geométrica. VAGEO

La variable C es el valor del primer semestre de la renta valorado a final de semestre:

=VF(F13;6;-F64;;1)

El montante M de la celda F66 se obtiene así:

=VFgeo(F65;1,05;20;F14)

Finalmente Solver se encarga de obtener el valor de la primera mensualidad a.

Geometrica Fraccionada con faltas

Un empresario alquila una nave industrial durante 25 años. Cobra al inicio de cada mes durante el primer año 20.000 euros, y pacta incrementos del 3% anual acumulado. El inquilino le propone que él se hará cargo de todos los gastos de la nave, si la última mensualidad de cada año se la reduce a la mitad. El empresario acepta la propuesta, y desea conocer el valor actual del arrendamiento valorado al 6% efectivo anual.

---

La renta es prepagable, de 300 meses. La última cuantía vence en t=299 y es de 20.327,94 euros.

Dentro de cada año los 11 primeros meses son iguales y el último (el 12º) es la mitad. Lo que sucede es que al ser la renta prepagable el ultimo mes queda en el instante t=11 para el primer año.

Esta es una renta geométrica fraccionada. Esto quiere decir que la renta verdaderamente geométrica no es la renta mensual sino la renta anual. En este caso es anual ya que el incremento del 3% acumulado es anual.

Debemos calcular una renta anual financieramente equivalente a la renta mensual. O dicho en otras palabras, debemos anualizar la renta. Esto se logra llevando la renta de cada año a final de su año. Por tanto para el primer año, la renta llevada hasta t=12, en caso de no tener faltas, sería:

=VF(i12;12;-20000;;1)

Pero como tiene una falta en t=11, que lo que hace es reducir los 20.000 euros a la mitad, debemos quitar a esa renta esos 10.000 euros que le faltan. Pero debemos quitárselos valorados tambien en t=12. Por tanto el VF de la renta del primer año, valorada en t=12 y, ahora si considerando la falta, es:

=VF(i12;12;-20000;;1)-10000*(1+i12)

los 10.000 euros que hemos restado se capitalizan un mes (se multiplica por (1+i12)), debido a que los 10.000 de la falta estan en t=11 y nosotros estamos valorando un mes más tarde, en t=12.

Por tanto, la expresión anterior hace el papel de C en el valor actual de una renta variable en progresión geométrica anual. Su valor actual usando VAgeo es:

=VAgeo(C;q;n;i)

Donde

C es:

=VF(i12;12;-20000;;1)-10000*(1+i12)

q es: 1,03

n es el número de años = 25

i es el tipo de interés efectivo anual = 6%.

Método 1

Primero construimos la renta.

Ponemos a mano las cuantías del primer año, desde t=0 hasta t=11, ya que la renta es prepagable.

• La celda C26 es: =C14*$F$12. Luego se copia hacia abajo.

Para calcular el valor actual calculamos el VAN de la renta, sabiendo que es una renta prepagable.

=VNA(F14;C14:C312)+C13

Método 2

Mira el siguiente Post que incluye un vídeo para programar VAgeo:

Valor Financiero de una Renta Geométrica. VAGEO

=vageo(VF(F14;12;-C13;;1)-C24*(1+F14);F12;25;F13)

Método 3

=vageo(VF(F14;12;-C13;;1);F12;25;F13)-vageo(C24*(1+F14);F12;25;F13)

Método 4

=vageo(VF(F14;12;-C13;;1);F12;25;F13)-vageo(C24;F12;25;F13)*(1+F14)

Método 5

En este caso, lo que haremos es anualizar la renta y tratarla luego como una geométrica normal.

Podemos calcular las anualidades que nos darán una renta anual pospagable que es financieramente equivalente a la renta mensual.

Tomamos las 12 primeras cuantías y las valoramos al final del primer año. Eso nos dará la primera anualidad, que luego haremos crecer un 3% anual acumulado, ya que q=1,03.

• La celda F25 es: =+VF(F14;12;-20000;;1)-10000*(1+F14)
• La celda F26 es: =+F25*$F$12. Luego se copia hacia abajo.

Finalmente aplicamos la función VNA al 6% anual a la renta anualizada y tendremos el valor actual de la renta.

=VNA(F13;F25:F49)

Resolución manual

Rentabilidad conjunta de dos operaciones

Un ahorrador invierte 100.000 euros en el siguiente producto financiero ofrecido por su banco.
* Inversión a 6 años.
* El tipo de interés nominal anual ofrecido durante cada año aumenta un punto, siendo el ofrecido durante el primer año del 3% nominal anual. Así, el sexto año el tanto aplicable será del 8% nominal anual.
* Pago de intereses trimestralmente.
Los intereses recibidos los ingresa en una cuenta remunerada al 3% nominal anual.
Calcular la rentabilidad anual efectiva conjunta obtenida por el inversor.

---

Vamos a despejar i de la Ley de Capitalización Compuesta.

Cn=Co(1+i)^n

Cn/Co=(1+i)^n

(1+i)^n=(Cn/Co)

Elevando ambos miembros de una igualdad a un mismo número la igualdad permanece.

Si A=A entonces A^x=A^x

Nosotros vamos a elevar a (1/n) en ambos miembros de la igualdad.

((1+i)^n)^ (1/n)=(Cn/Co)^ (1/n)

Ahora aplicamos la propiedad que dice que "potencia de potencia es igual a producto": (A^x)^y=A^(xy)

Y como: n*(1/n)=1

entonces:

(1+i)=(Cn/Co)^ (1/n)

finalmente:

i=[(Cn/Co)^ (1/n)]-1

En Excel tenemos la función TASA que despeja por nosotros de una forma mucho más sencilla.

• La celda D17 es: =BUSCARV(C17;$G$18:$J$23;4)
• La celda E17 es: =+E16*(1+$H$27)+D17
• La celda J18 es: =+I18*$H$15
• La celda H33 es: =+E40+H15
• La celda I33 es: =+VNA(H27;D17:D40)*(1+H27)^24+H15
• La celda J33 es:
  =+VAaritmetica(VF(H27;4;-D17);VF(H27;4;-250);6;(1+H27)^4-1)*(1+H27)^24+H15
• La celda H34 es: =+(H33/H32)^(1/6)-1
• La celda I34 es: =TASA(6;;I32;I33)
• La celda J34 es: =(1+TIR(J32:J33))^(1/6)-1

La función VAaritmecia calcula el valor actual de una renta variable en progresión aritmética y se puede programar (al igual que se programó VAgeo). La función es la siguiente:


Function VAaritmetica(C, d, n, i)
    VAaritmetica = (C + d / i + d * n) * (1 - (1 + i) ^ -n) / i - (d * n / i)
End Function

Financiación sin intereses

Un joven desea adquirir un ciclomotor cuyo precio de venta al público (PVP) es de 4.200 €. La tienda le ofrece dos opciones de pago:
Opción A: Pago al contado con un descuento del 10% sobre el PVP.
Opción B: Pago aplazado sin intereses. Únicamente tendrá que abonar 12 pagos al inicio de cada mes para cubrir el PVP.
El joven no dispone de efectivo en este mometo para efectuar la compra al contado, pero puede solicitar un préstamo a un banco, que le aplicaría un tanto r (efectivo anual). Calcular r para que al joven cliente le resulte indiferente pedir el préstamo al banco o acogerse a la opción B de pago que ofrece la tienda.

---

Este problema es un estupendo ejemplo que permite ver que aunque te digan que te ofrecen financiación a tipo cero, eso no significa que tu coste financiero sea cero. Más bien al contrario, nos sale un coste del 26,472%, que no es un porcentaje despreciable.

El quitz de la cuestión está en que la opción de pago A lleva aparejada un descuento del 10% sobre el PVP (Precio de Venta al Público). Esto supone, por tanto, que la financiación de la modalidad B no es gratis, ya que si opto por la modalidad B no me beneficio del 10% de descuento. Esto se ve muy bien si en lugar de pensar en un 10% piensas en una cifra mayor, exagerando un poco, imagina un 50% de descuento.

El cliente para no renunciar al descuento de la modalidad A, puede pedir un préstamo personal a su banco. Importante: ¿De qué importe pedirá el préstamo? ¿De 4.200 euros o de 3.780 euros?. Lógicamente pedirá el préstamo de 3.780 euros, que es la cifra que necesita para optar por la modalidad A de pago.

Observar, que nunca jamás el cliente paga 4.200 euros en t=0, ya que o bien paga los 3.780 en t=0 (modalidad de pago A), o bien, paga una renta prepagable de 350 euros durante 12 meses. Y aqui todos tenemos la tentación de multiplicar 12x350 y decir que es igual a 4.200 euros. Pero debemos, vencer esa tendencia a multiplicar, que es lo mismo que sumar aritméticamente cuantías disponibles en distinto momento del tiempo, ya que en finanzas esto no se puede hacer. Pero quizás, me digas que si se puede hacer en el caso de que el tipo de interés sera cero, y este es el caso. A lo cual yo te responderé que, efectivamente valorar a tipo cero es como sumar cuantías, pero que en este caso no estamos a tipo cero, y ese es precisamente el tipo de interés que vamos a calcular enfrentando las dos modalidades de pago.

Por tanto, tenemos una operación financiera que tiene una prestación en t=0 de 3.780 euros, y una contraprestación que es una renta prepagable mensual de 12 términos de 350 euros. El tipo de interés que equilibra prestación y contraprestación valoradas en el instante del tiempo que quieras, será la tasa mensual, que anualizada nos de el coste financiero de la operación. Por eso calculamos una columan de 'Diferencia' que contienen los flujos de caja, y aplicamos la TIR, cuyo resultado sera mensual, y que luego anualizamos.

Se puede razonar de otra forma. ¿Qué importe mensual tendré que pagar a mi banco para amortizar un préstamo que he tenido que pedir de 3.780 euros?. Si la renta que debes dar a tu banco también es prepagable de 12 términos constantes, verás que si aplicas el tipo de interés que te ha salido antes, la cantidad es justo 350 euros. Lo cual constituye una comprobación de que esta bien calculado.

Para comparar dos opciones de pago (o cobro) calculamos la columna de Diferencia, y aplicamos al TIR sobre ella. La TIR resultante nos indica a que tipo de interés ambas opciones son equivalentes.

Si la función TIR se aplica sobre flujos mensuales lo que obtenemos es la TIR mensual, que luego tendremos que anualizar para obtener la TIR.

• La celda G16 es: =TIR(E20:E31)
• La celda G17 es: =TASA(12;C16;-C20;;1)

Fondo, Letras y préstamo

Durante 5 años, un inversor aporta a un fondo 596 € al inicio de cada semestre, que son remunerados al 5% efectivo anual. El montante alcanzado a los 5 años supone el 80% del precio de 9 Letras del Tesoro de nominal 1.000 € cada una, y vencimiento a un año. Para conseguir el resto del precio de las Letras solicita un préstamo a tipo fijo r efectivo anual, a devolver mediante un solo pago transcurrido un año. Calcular r sabiendo que la rentabilidad conjunta del inversor ha sido del 5% efectivo anual.

---

Método 1

1. Calculas el montante M
2. Calculas el efectivo pagado por las 9 Letras: E
3. Calculas el Co del préstamo
4. Te inventas un valor para Cn, por ejemplo 1.800 euros
5. Calculas X
6. Calculas la TIR de la operación conjunta
7. Pides a Solver que haga que la TIR conjunta sea del 5% y que para ello calcule Cn
8. Con la función TASA calculas r. También se puede calcular aplicando la TIR al préstamo

Método 2

Sin necesidad de usar Solver, trabajando únicamente con funciones.

1. Calculas el montante M
2. Calculas el efectivo pagado por las 9 Letras: E
3. Calculas el Co del préstamo
4. Calculas X
5. Calculas Cn
6. Calculas r

Fórmula 10

Un ordenador cuyo precio es P se puede adquirir mediante la llamada "Fórmula 10", que consiste en pagar el 10% de P en el momento de la compra, más diez pagos mensuales del mismo importe (10% de P), venciendo el primero de ellos al mes de haber adquirido el ordenador. Si se compra al contado se efectuará un descuento del 10% de P. Sea r el coste financiero de la "Fórmula 10" expresado en tanto efectivo anual. Calcular r.

---

Ver problema 2.33 del Libro.

Planteando el problema con ecuaciones la variable P se simplifica y no aparece en la ecuación final, por lo que la solución no depende del precio P que tomemos.

Para resolverlo en Excel te debes inventar un precio del ordenador. Yo me inventé 1.000 euros, pero es cierto que últimamente han bajado mucho de precio.

En t=10 también se paga el 10% de P, porque son 10 pagos, más el pago inicial. Por tanto, la contraprestación esta formada por 11 pagos prepagables de 100 euros.

Este problema esta sacado de una formula de financiación que usaban hace no muchos años para la compra de productos de electrónica. Lo anunciaban en la publicidad de una conocida cadena de tiendas de electrónica de consumo. Además se llamaba justamente así: "Fórmula 10". Consiste en que pagas el 10% de P durante 10 meses, como renta POS-pagable (inicio en t=1 y final en t=10). Y además pagas, también el 10% de P en t=0. Por tanto si sumas todo lo que pagas de forma aritmética sale que pagas 1,1P, que es más que P, ya que aquí si te cobran intereses.

Dos incógnitas

Una empresa tiene que hacer frente, dentro de un año, a un pago de 800.000 €. Hace dos años, ingresó la cantidad de C € necesaria para poder realizar dicho pago, en una entidad bancaria que ofrecía un tipo de interés efectivo anual, i.
En estos momentos, la entidad bancaria anuncia una reducción de los tipos de interés, y remunerará sus cuentas corrientes a un 4% efectivo anual. La empresa se ve obligada a efectuar 12 ingresos mensuales de importe 500 €, el primero de ellos en este mismo momento, para poder obtener los 800.000 €.
Calcular i.

---

Ver problema 2.36 del Libro.

Vamos a plantear el problema con ecuaciones.

Método 1

Con Solver no podemos despejar a la vez dos incógnitas. Por eso, cuando se presenta un caso como este, de dos ecuaciones con dos incógnitas, debemos plantear el problema y en una celda poner una variable en función de la otra. O dicho de otro modo, debes facilitar a Solver el despejar una variable en función de la otra. En nuestro caso hemos elegido despejar C, que es:

C = 800.000 / (1+i)^3

Esta expresión la tenemos que poner en nuestra hoja en alguna celda, y cuando se necesite usar C se vincula con esta celda, que a su vez depende de i. De esta forma, tendremos relacionadas la C y la i para que Solver pueda calcularlas.

La celda J16 es precisamente esta fórmula, es C:

=800000/(1+J14)^3

La celda J17 es:

=SUMA(G15:G50)+F51

La J18 que es la comprobación es:

=F15*(1+J14)^2*(1+J15)+VF((1+J15)^(1/12)-1;12;-F39;;1)

La celda G15 es:

=F15*PRODUCTO(E16:$E$51)

Por tanto, lo importante cuando tenemos dos incógnitas es simplificarle a Solver el trabajo y convertirlas en una sola incógnita. ¿Cómo?. Despejando una en función de la otra.

Método 2

Podemos atacar un sistema de dos ecuaciones con dos incógnitas utilizando Solver. Pero requiere que lo trabajemos, ya que Solver únicamente tiene una función objetivo.

Lo que haremos es despejar una variable en función de la otra, y así únicamente tendremos una ecuación con una incógnita.

De la primera ecuación despejamos C y la sustituimos en la segunda ecuación.

1. En la celda C55 nos inventamos un valor para i, por ejemplo 4,50%.
2. En la celda C56 calculamos C. Para ello despejamos de la primera ecuación del Libro. =800000/(1+C55)^3
3. En la celda C57 ponemos la segunda ecuación del Libro igualada a cero. La expresión es la siguiente: =C56*(1+C55)^2*1,04+VF(1,04^(1/12)-1;12;-500;;1)-800000
4. Luego le pedimos a Solver que efectivamente haga cero la celda C57 para calcular la celda C55 que es donde esta la incógnita i.

Así con tres celdas y Solver seremos capaces de resolver el problema.

Método 3

Podemos despejar del sistema de ecuaciones el tanto i.

 =(800000*1,04/(800000-(VF(1,04^(1/12)-1;12;-500;;1))))-1